root/trunk/mixiComment/plugins/mixiComment/lib/mixiComment/Auth/mixi.pm @ 1066

package mixiComment::Auth::mixi;

use strict;
use base qw( MT::Auth::OpenID );

sub check_url_params {
    my $class = shift;
    my ( $app, $blog ) = @_;
    my $q = $app->{query};

    if ( $q->param('verify_blog_owner') ) {
        my $path = MT->config->AdminCGIPath || MT->config->CGIPath;
        $path = _adjust_path( $path, $blog );
        $path .= MT->config->AdminScript;
        my $return_to = $path . '?__mode=mixicomment_verify_blog_owner'
            . '&blog_id='  . $blog->id;
        return ( trust_root => $path, return_to => $return_to );
    }
    else {
        return $class->SUPER::check_url_params(@_);
    }
}

sub _adjust_path {
    my ( $path, $blog ) = @_;
    if ($path =~ m!^/!) {
        # relative path, prepend blog domain
        my ($blog_domain) = $blog->archive_url =~ m|(.+://[^/]+)|;
        $path = $blog_domain . $path;
    }
    $path .= '/' unless $path =~ m|/$|;
    $path;
}

# TODO: remove these once core code supports SREG - BugID:71011
sub NS_OPENID_SREG { "http://openid.net/extensions/sreg/1.1" }

sub login {
    my $class = shift;
    my ($app) = @_;
    my $q = $app->{query};
    return $app->errtrans("Invalid request.")
        unless $q->param('blog_id');
    my $blog = MT::Blog->load(scalar $q->param('blog_id'));
    my %param = $app->param_hash;
    my $csr = MT::Auth::OpenID::_get_csr(\%param, $blog) or return;
    my $identity = $q->param('openid_url');
    if (!$identity &&
        (my $u = $q->param('openid_userid')) && $class->can('url_for_userid')) {
        $identity = $class->url_for_userid($u);
    }
    my $claimed_identity = $csr->claimed_identity($identity);
    if (!$claimed_identity) {
        my ($err_code, $err_msg) = ($csr->errcode, $csr->errtext);
        if ($err_code eq 'no_head_tag' || $err_code eq 'no_identity_server' || $err_code eq 'url_gone') {
            $err_msg = $app->translate('The address entered does not appear to be an OpenID');
        }
        elsif ($err_code eq 'empty_url' || $err_code eq 'bogus_url') {
            $err_msg = $app->translate('The text entered does not appear to be a web address');
        }
        elsif ($err_code eq 'url_fetch_error') {
            $err_msg =~ s{ \A Error \s fetching \s URL: \s }{}xms;
            $err_msg = $app->translate('Unable to connect to [_1]: [_2]', $identity, $err_msg);
        }
        return $app->error($app->translate("Could not verify the OpenID provided: [_1]", $err_msg));
    }

    my %params = $class->check_url_params( $app, $blog );

    $claimed_identity->set_extension_args(NS_OPENID_SREG(), {
        optional => join(",", qw/email nickname fullname/)
    });

    my $check_url = $claimed_identity->check_url(
        ( %params, delayed_return => 1 )
    );

    return $app->redirect($check_url);
}

sub get_nickname {
    my $class = shift;
    my ($vident) = @_;

    # Try SREG extension first
    my $fields = $vident->extension_fields(NS_OPENID_SREG);
    my $nick = $fields->{nickname} if exists $fields->{nickname};
    $nick ||= $fields->{fullname} if exists $fields->{fullname};
    if ( $nick ) {
        if ( MT->config->PublishCharset !~ /utf-?8/i ) {
            $nick = MT::I18N::encode_text( MT::Util::decode_url($nick), 'UTF-8', MT->config->PublishCharset );
        }
        return $nick;
    }
    $class->SUPER::get_nickname(@_);
}

1;
__END__