root/trunk/OpenIDwithBanList/plugins/OpenIDwithBanList/lib/OpenID/WithBanList.pm @ 385

# OpenIDwithBanList plugin for Movable Type
# Author: Fumiaki Yoshimatsu (http://www.luckypines.com/mt/)
# Released under the Artistic License.

package OpenID::WithBanList;
use strict;
use base qw( MT::Auth::OpenID );

sub login {
    my $class = shift;
    my ($app) = @_;
    my $q = $app->{query};
    return $app->errtrans("Invalid request.")
        unless $q->param('blog_id');
    my $blog = $app->model('blog')->load($q->param('blog_id'))
        or return $app->errtrans("Invalid request.");
    my %param = $app->param_hash;
    my $csr = MT::Auth::OpenID::_get_csr(\%param, $blog) or return;
    my $identity = $q->param('openid_url');
    if (!$identity &&
        (my $u = $q->param('openid_userid')) && $class->can('url_for_userid')) {
        $identity = $class->url_for_userid($u);
    }
    my $claimed_identity = $csr->claimed_identity($identity);
    if ( $claimed_identity && ( my $idp_server = $claimed_identity->{server} ) ) {
        # check to see if the server is in the ban list
        my $banned = 0;
        require MT::PluginData;
        my $plugindata = MT::PluginData->get_by_key({ plugin => 'OpenID::WithBanList', key => $blog->id . "_banlist" });
        if ( $plugindata ) {
            my $list = $plugindata->data || [];
            for my $hash ( @$list ) {
                my $url = $hash->{url};
                if ( $idp_server =~ m|$url|i ) {
                    $banned = 1;
                    MT->log( 
                        $app->translate('Banned login attempt by OpenID [_1].  [_2] is banned.', $identity, $url)
                    );
                    return $app->errtrans('Your OpenID may be valid but you cannot use it here.  Try different OpenID.');
                }
            }
        }
    }
    $class->SUPER::login(@_);
}

sub list_idp {
    my $app = shift;
    my $q = $app->param;

    return $app->errtrans("Invalid request.")
        unless $q->param('blog_id');
    my $blog = $app->model('blog')->load($q->param('blog_id'))
        or return $app->errtrans("Invalid request.");

    require MT::PluginData;
    my $plugindata = MT::PluginData->get_by_key({ plugin => 'OpenID::WithBanList', key => $blog->id . "_banlist" });

    $app->load_tmpl( 'list_idps.tmpl', {
        blog_id => $blog->id,
        object_loop => $plugindata->data,
    });
}

sub add_idp {
    my $app = shift;
    my $q = $app->param;

    return $app->errtrans("Invalid request.")
        unless $q->param('blog_id');
    my $blog = $app->model('blog')->load($q->param('blog_id'))
        or return $app->errtrans("Invalid request.");
    return $app->errtrans("Invalid request.")
        unless $q->param('new_url');
    my $url = MT::Util::encode_html($q->param('new_url'));

    $app->validate_magic() or return;

    # First ban the existing commenters...
    my $cmntr_iter = $app->model('commenter')->load_iter({
        name => { like => "%$url%" },
        type => MT::Author::COMMENTER(),
        auth_type => [ 'OpenID', 'openid_banlist' ],
    });
    while ( my $cmntr = $cmntr_iter->() ) {
        next if MT::Author::BANNED() == $cmntr->commenter_status($blog->id);
        $cmntr->ban($blog->id);
    }

    my $param = {
        blog_id => $blog->id,
    };

    require MT::PluginData;
    my $plugindata = MT::PluginData->get_by_key({ plugin => 'OpenID::WithBanList', key => $blog->id . "_banlist" });
    if ( $plugindata ) {
        my $list = $plugindata->data || [];
        my @keys = map { $_->{idp_id} } @$list;
        @keys = sort { $b <=> $a } @keys;
        my $next = $keys[0] + 1;
        push @$list, { idp_id => $next, url => $url };
        $plugindata->data($list);
        if ( $plugindata->save() ) {
            $param->{saved} = 1;
        }
        else {
            $param->{error} = $plugindata->errstr;
        }
        $param->{object_loop} = $list;
    }
    $app->load_tmpl( 'list_idps.tmpl', $param);
}

sub delete_idp {
    my $app = shift;
    my $q = $app->param;

    return $app->errtrans("Invalid request.")
        unless $q->param('blog_id');
    my $blog = $app->model('blog')->load($q->param('blog_id'))
        or return $app->errtrans("Invalid request.");

    $app->validate_magic() or return;

    my $param = {
        blog_id => $blog->id,
    };

    require MT::PluginData;
    my $plugindata = MT::PluginData->get_by_key({ plugin => 'OpenID::WithBanList', key => $blog->id . "_banlist" });
    if ( $plugindata ) {
        my $list = $plugindata->data || [];
        my %id_hash = map { $_ => 1 } $q->param('id');
        my @new_list = map { $_ } grep { !exists( $id_hash{ $_->{idp_id} } ) } @$list;
        $plugindata->data(\@new_list);
        if ( $plugindata->save() ) {
            $param->{saved_deleted} = 1;
        }
        else {
            $param->{error} = $plugindata->errstr;
        }
        $param->{object_loop} = \@new_list;
    }
    $app->load_tmpl( 'list_idps.tmpl', $param);
}

1;