root/branches/release-33/lib/MT/XMLRPCServer.pm @ 1724

Revision 1724, 45.9 kB (checked in by bchoate, 20 months ago)

Issue blog->touch calls for XMLRPC updates. BugId:75087
  • Property svn:keywords set to Author Date Id Revision
Line 
1# Movable Type (r) Open Source (C) 2001-2008 Six Apart, Ltd.
2# This program is distributed under the terms of the
3# GNU General Public License, version 2.
4#
5# $Id$
6
7package MT::XMLRPCServer::Util;
8use strict;
9use Time::Local qw( timegm );
10use MT::Util qw( offset_time_list );
11use MT::I18N qw( encode_text first_n_text const );
12
13sub mt_new {
14    my $cfg = $ENV{MOD_PERL} ?
15        Apache->request->dir_config('MTConfig') :
16        $MT::XMLRPCServer::MT_DIR . '/mt-config.cgi';
17    my $mt = MT->new( Config => $cfg )
18        or die MT::XMLRPCServer::_fault(MT->errstr);
19    # we need to be UTF-8 here no matter which PublishCharset
20    $main::server->serializer->encoding('UTF-8');
21    $mt->run_callbacks('init_app', $mt, {App => 'xmlrpc'});
22    $mt;
23}
24
25sub iso2ts {
26    my($blog, $iso) = @_;
27    die MT::XMLRPCServer::_fault(MT->translate("Invalid timestamp format"))
28        unless $iso =~ /^(\d{4})(?:-?(\d{2})(?:-?(\d\d?)(?:T(\d{2}):(\d{2}):(\d{2})(?:\.\d+)?(Z|[+-]\d{2}:\d{2})?)?)?)?/;
29    my($y, $mo, $d, $h, $m, $s, $offset) =
30    ($1, $2 || 1, $3 || 1, $4 || 0, $5 || 0, $6 || 0, $7);
31    if ($offset && !MT->config->IgnoreISOTimezones) {
32        $mo--;
33        $y -= 1900;
34        my $time = timegm($s, $m, $h, $d, $mo, $y);
35        ## If it's not already in UTC, first convert to UTC.
36        if ($offset ne 'Z') {
37            my($sign, $h, $m) = $offset =~ /([+-])(\d{2}):(\d{2})/;
38            $offset = $h * 3600 + $m * 60;
39            $offset *= -1 if $sign eq '-';
40            $time -= $offset;
41        }
42        ## Now apply the offset for this weblog.
43        ($s, $m, $h, $d, $mo, $y) = offset_time_list($time, $blog);
44        $mo++;
45        $y += 1900;
46    }
47    sprintf "%04d%02d%02d%02d%02d%02d", $y, $mo, $d, $h, $m, $s;
48}
49
50sub ts2iso {
51    my ($blog, $ts) = @_;
52    my ($yr, $mo, $dy, $hr, $mn, $sc) = unpack('A4A2A2A2A2A2A2', $ts);
53    $ts = timegm($sc, $mn, $hr, $dy, $mo, $yr);
54    ($sc, $mn, $hr, $dy, $mo, $yr) = offset_time_list($ts, $blog, '-');
55    $yr += 1900;
56    sprintf("%04d-%02d-%02d %02d:%02d:%02d", $yr, $mo, $dy, $hr, $mn, $sc);
57}
58
59package MT::XMLRPCServer;
60use strict;
61
62use MT;
63use MT::Util qw( first_n_words decode_html start_background_task archive_file_for );
64use MT::I18N qw( encode_text first_n_text const );
65use base qw( MT::ErrorHandler );
66
67our $MT_DIR;
68
69my($HAVE_XML_PARSER);
70BEGIN {
71    eval { require XML::Parser };
72    $HAVE_XML_PARSER = $@ ? 0 : 1;
73}
74
75sub _fault {
76    my $mt = MT::XMLRPCServer::Util::mt_new();
77    my $enc = $mt->config('PublishCharset');
78    SOAP::Fault->faultcode(1)->faultstring(
79        SOAP::Data->type(
80            string => encode_text($_[0], $enc, 'utf-8')));
81}
82
83## This is sort of a hack. XML::Parser automatically makes everything
84## UTF-8, and that is causing severe problems with the serialization
85## of database records (what happens is this: we construct a string
86## consisting of pack('N', length($string)) . $string. If the $string SV
87## is flagged as UTF-8, the packed length is then upgraded to UTF-8,
88## which turns characters with values greater than 128 into two bytes,
89## like v194.129. And so on. This is obviously now what we want, because
90## pack produces a series of bytes, not a string that should be mucked
91## about with.)
92##
93## The following subroutine strips the UTF8 flag from a string, thus
94## forcing it into a series of bytes. "pack 'C0'" is a magic way of
95## forcing the following string to be packed as bytes, not as UTF8.
96
97sub no_utf8 {
98    for (@_) {
99        next if ref;
100        $_ = pack 'C0A*', $_;
101    }
102}
103
104sub _make_token {
105    my @alpha = ('a'..'z', 'A'..'Z', 0..9);
106    my $token = join '', map $alpha[rand @alpha], 1..40;
107    $token;
108}
109
110sub _login {
111    my $class = shift;
112    my($user, $pass, $blog_id) = @_;
113    no_utf8($user, $pass);
114    my $mt = MT::XMLRPCServer::Util::mt_new();
115    my $enc = $mt->config('PublishCharset');
116    $user = encode_text($user, 'utf-8', $enc);
117    $pass = encode_text($pass, 'utf-8', $enc);
118    require MT::Author;
119    my $author = MT::Author->load({ name => $user, type => 1 }) or return;
120    die _fault(MT->translate("No web services password assigned.  Please see your user profile to set it.")) unless $author->api_password;
121    die _fault(MT->translate("Failed login attempt by disabled user '[_1]'")) unless $author->is_active;
122    my $auth = $author->api_password eq $pass;
123    $auth ||= crypt($pass, $author->api_password) eq $author->api_password;
124    return unless $auth;
125    return $author unless $blog_id;
126    require MT::Permission;
127    my $perms = MT::Permission->load({ author_id => $author->id,
128                                       blog_id => $blog_id });
129
130    ## update session so the user will be counted as active
131    require MT::Session;
132    my $sess_active = MT::Session->load( { kind => 'UA', name => $author->id } );
133    if (!$sess_active) {
134        $sess_active = MT::Session->new;
135        $sess_active->id(_make_token());
136        $sess_active->kind('UA'); # UA == User Activation
137        $sess_active->name($author->id);
138    }
139    $sess_active->start(time);
140    $sess_active->save;
141
142    ($author, $perms);
143}
144
145sub _publish {
146    my $class = shift;
147    my($mt, $entry, $no_ping) = @_;
148    require MT::Blog;
149    my $blog = MT::Blog->load($entry->blog_id);
150    $mt->rebuild_entry( Entry => $entry, Blog => $blog,
151                        BuildDependencies => 1 )
152        or return $class->error("Publish error: " . $mt->errstr);
153    unless ($no_ping) {
154        $mt->ping_and_save(Blog => $blog, Entry => $entry)
155            or return $class->error("Ping error: " . $mt->errstr);
156    }
157    1;
158}
159
160sub _apply_basename {
161    my $class = shift;
162    my ($entry, $item, $param) = @_;
163
164    my $basename = $item->{mt_basename} || $item->{wp_slug};
165    if ($param->{page} && $item->{permaLink}) {
166        local $entry->{column_values}->{basename} = '##s##';
167        my $real_url = $entry->archive_url();
168        my ($pre, $post) = split /##s##/, $real_url, 2;
169       
170        my $req_url = $item->{permaLink};
171        if ($req_url =~ m{ \A \Q$pre\E (.*) \Q$post\E \z }xms) {
172            my $req_base = $1;
173            my @folders = split /\//, $req_base;
174            $basename = pop @folders;
175            $param->{__permaLink_folders} = \@folders;
176        }
177        else {
178            die _fault(MT->translate("Requested permalink '[_1]' is not available for this page",
179                $req_url));
180        }
181    }
182
183    if (defined $basename) {
184        # Ensure this basename is unique.
185        my $entry_class = ref $entry;
186        my $basename_uses = $entry_class->count({
187            blog_id  => $entry->blog_id,
188            basename => $basename,
189            ($entry->id ? ( id => { op => '!=', value => $entry->id } ) : ()),
190        });
191        if ($basename_uses) {
192            $basename = MT::Util::make_unique_basename($entry);
193        }
194
195        $entry->basename($basename);
196    }
197
198    1;
199}
200
201sub _save_placements {
202    my $class = shift;
203    my ($entry, $item, $param) = @_;
204
205    my @categories;
206    my $changed = 0;
207
208    if ($param->{page}) {
209        if (my $folders = $param->{__permaLink_folders}) {
210            my $parent_id = 0;
211            my $folder;
212            require MT::Folder;
213            for my $basename (@$folders) {
214                $folder = MT::Folder->load({
215                    blog_id  => $entry->blog_id,
216                    parent   => $parent_id,
217                    basename => $basename,
218                });
219
220                if (!$folder) {
221                    # Autovivify the folder tree.
222                    $folder = MT::Folder->new;
223                    $folder->blog_id($entry->blog_id);
224                    $folder->parent($parent_id);
225                    $folder->basename($basename);
226                    $folder->label($basename);
227                    $changed = 1;
228                    $folder->save
229                      or die _fault(MT->translate("Saving folder failed: [_1]",
230                        $folder->errstr));
231                }
232
233                $parent_id = $folder->id;
234            }
235            @categories = ($folder) if $folder;
236        }
237    }
238    elsif (my $cats = $item->{categories}) {
239        if (@$cats) {
240            my $cat_class = MT->model('category');
241            # The spec says to ignore invalid category names.
242            @categories = grep { defined } $cat_class->search({
243                blog_id => $entry->blog_id,
244                label   => $cats,
245            });
246        }
247    }
248
249    require MT::Placement;
250    my $is_primary_placement = 1;
251    CATEGORY: for my $category (@categories) {
252        my $place;
253        if ($is_primary_placement) {
254            $place = MT::Placement->load({
255                entry_id   => $entry->id,
256                is_primary => 1,
257            });
258        }
259        if (!$place) {
260            $place = MT::Placement->new;
261            $place->blog_id($entry->blog_id);
262            $place->entry_id($entry->id);
263            $place->is_primary($is_primary_placement ? 1 : 0);
264        }
265        $place->category_id($category->id);
266        $place->save
267          or die _fault(MT->translate("Saving placement failed: [_1]",
268            $place->errstr));
269
270        if ($is_primary_placement) {
271            # Delete all the secondary placements, so each of the remaining
272            # iterations of the loop make a brand new placement.
273            my @old_places = MT::Placement->load({
274                entry_id => $entry->id,
275                is_primary => 0,
276            });
277            for my $place (@old_places) {
278                $place->remove;
279            }
280        }
281
282        $is_primary_placement = 0;
283    }
284
285    $changed;
286}
287
288sub _new_entry {
289    my $class = shift;
290    my %param = @_;
291    my($blog_id, $user, $pass, $item, $publish) =
292        @param{qw( blog_id user pass item publish )};
293    my $obj_type = $param{page} ? 'page' : 'entry';
294    die _fault(MT->translate("No blog_id")) unless $blog_id;
295    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
296    no_utf8($blog_id, values %$item);
297    for my $f (qw( title description mt_text_more
298                   mt_excerpt mt_keywords mt_tags mt_basename wp_slug )) {
299        next unless defined $item->{$f}; 
300        my $enc = $mt->{cfg}->PublishCharset;
301        $item->{$f} = encode_text($item->{$f}, 'utf-8', $enc);
302        unless ($HAVE_XML_PARSER) {
303            $item->{$f} = decode_html($item->{$f});
304            $item->{$f} =~ s!'!'!g;  #'
305        }
306    }
307    require MT::Blog;
308    my $blog = MT::Blog->load($blog_id)
309        or die _fault(MT->translate("Invalid blog ID '[_1]'", $blog_id));
310    my($author, $perms) = $class->_login($user, $pass, $blog_id);
311    die _fault(MT->translate("Invalid login")) unless $author;
312    die _fault(MT->translate("Permission denied.")) unless $perms && $perms->can_create_post;
313    my $entry = MT->model($obj_type)->new;
314    my $orig_entry = $entry->clone;
315    $entry->blog_id($blog_id);
316    $entry->author_id($author->id);
317
318    ## In 2.1 we changed the behavior of the $publish flag. Previously,
319    ## it was used to determine the post status. That was a bad idea.
320    ## So now entries added through XML-RPC are always set to publish,
321    ## *unless* the user has set "NoPublishMeansDraft 1" in mt.cfg, which
322    ## enables the old behavior.
323    if ($mt->{cfg}->NoPublishMeansDraft) {
324        $entry->status($publish && $perms->can_publish_post ? MT::Entry::RELEASE() : MT::Entry::HOLD());
325    } else {
326        $entry->status($perms->can_publish_post ? MT::Entry::RELEASE() : MT::Entry::HOLD() );
327    }
328    $entry->allow_comments($blog->allow_comments_default);
329    $entry->allow_pings($blog->allow_pings_default);
330    $entry->convert_breaks(defined $item->{mt_convert_breaks} ? $item->{mt_convert_breaks} : $blog->convert_paras);
331    $entry->allow_comments($item->{mt_allow_comments})
332        if exists $item->{mt_allow_comments};
333    $entry->title($item->{title})
334        if exists $item->{title};
335
336    $class->_apply_basename($entry, $item, \%param);
337
338    $entry->text($item->{description});
339    for my $field (qw( allow_pings )) {
340        my $val = $item->{"mt_$field"};
341        next unless defined $val;
342        die _fault(MT->translate("Value for 'mt_[_1]' must be either 0 or 1 (was '[_2]')", $field, $val))
343            unless $val == 0 || $val == 1;
344        $entry->$field($val);
345    }
346    $entry->excerpt($item->{mt_excerpt}) if $item->{mt_excerpt};
347    $entry->text_more($item->{mt_text_more}) if $item->{mt_text_more};
348    $entry->keywords($item->{mt_keywords}) if $item->{mt_keywords};
349
350    if (my $tags = $item->{mt_tags}) {
351        require MT::Tag;
352        my $tag_delim = chr($author->entry_prefs->{tag_delim});
353        my @tags = MT::Tag->split($tag_delim, $tags);
354        $entry->set_tags(@tags);
355    }
356    if (my $urls = $item->{mt_tb_ping_urls}) {
357        no_utf8(@$urls);
358        $entry->to_ping_urls(join "\n", @$urls);
359    }
360    if (my $iso = $item->{dateCreated}) {
361        $entry->authored_on(MT::XMLRPCServer::Util::iso2ts($blog, $iso))
362            || die MT::XMLRPCServer::_fault(MT->translate("Invalid timestamp format"));
363        my @ts = MT::Util::offset_time_list(time, $blog_id);
364        my $ts = sprintf '%04d%02d%02d%02d%02d%02d',
365            $ts[5]+1900, $ts[4]+1, @ts[3,2,1,0];
366        $entry->status(MT::Entry::FUTURE())
367            if ($entry->authored_on > $ts);
368    }
369    $entry->discover_tb_from_entry();
370
371    MT->run_callbacks("api_pre_save.$obj_type", $mt, $entry, $orig_entry)
372        || die MT::XMLRPCServer::_fault(MT->translate("PreSave failed [_1]", MT->errstr));
373
374    $entry->save;
375
376    my $changed = $class->_save_placements($entry, $item, \%param);
377
378    my @types = ( $obj_type );
379    if ($changed) {
380        push @types, 'folder'; # folders are the only type that can be
381                               # created in _save_placements
382    }
383    $blog->touch( @types );
384    $blog->save;
385
386    MT->run_callbacks("api_post_save.$obj_type", $mt, $entry, $orig_entry);
387
388    require MT::Log;
389    $mt->log({
390        message => $mt->translate("User '[_1]' (user #[_2]) added [lc,_4] #[_3]", $author->name, $author->id, $entry->id, $entry->class_label),
391        level => MT::Log::INFO(),
392        class => $obj_type,
393        category => 'new',
394        metadata => $entry->id
395    });
396
397    if ($publish) {
398        $class->_publish($mt, $entry) or die _fault($class->errstr);
399    }
400    delete $ENV{SERVER_SOFTWARE};
401    SOAP::Data->type(string => $entry->id);
402}
403
404sub newPost {
405    my $class = shift;
406    my($appkey, $blog_id, $user, $pass, $item, $publish);
407    if ($class eq 'blogger') {
408        ($appkey, $blog_id, $user, $pass, my($content), $publish) = @_;
409        $item->{description} = $content;
410    } else {
411        ($blog_id, $user, $pass, $item, $publish) = @_;
412    }
413    $class->_new_entry( blog_id => $blog_id, user => $user, pass => $pass,
414        item => $item, publish => $publish );
415}
416
417sub newPage {
418    my $class = shift;
419    my ($blog_id, $user, $pass, $item, $publish) = @_;
420    $class->_new_entry( blog_id => $blog_id, user => $user, pass => $pass,
421        item => $item, publish => $publish, page => 1 );
422}
423
424sub _edit_entry {
425    my $class = shift;
426    my %param = @_;
427    my ($blog_id, $entry_id, $user, $pass, $item, $publish) =
428        @param{qw( blog_id entry_id user pass item publish )};
429    my $obj_type = $param{page} ? 'page' : 'entry';
430    die _fault(MT->translate("No entry_id")) unless $entry_id;
431    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
432    no_utf8(values %$item);
433    for my $f (qw( title description mt_text_more
434                   mt_excerpt mt_keywords mt_tags mt_basename wp_slug )) {
435        next unless defined $item->{$f}; 
436        my $enc = $mt->config('PublishCharset');
437        $item->{$f} = encode_text($item->{$f}, 'utf-8', $enc);
438        unless ($HAVE_XML_PARSER) {
439            $item->{$f} = decode_html($item->{$f});
440            $item->{$f} =~ s!'!'!g;  #'
441        }
442    }
443    my $entry = MT->model($obj_type)->load($entry_id)
444        or die _fault(MT->translate("Invalid entry ID '[_1]'", $entry_id));
445    if ($blog_id && $blog_id != $entry->blog_id) {
446        die _fault(MT->translate("Invalid entry ID '[_1]'", $entry_id));
447    }
448    require MT::Blog;
449    my $blog = MT::Blog->load($blog_id)
450        or die _fault(MT->translate("Invalid blog ID '[_1]'", $blog_id));
451    my($author, $perms) = $class->_login($user, $pass, $entry->blog_id);
452    die _fault(MT->translate("Invalid login")) unless $author;
453    die _fault(MT->translate("Not privileged to edit entry"))
454        unless $perms && $perms->can_edit_entry($entry, $author);
455    my $orig_entry = $entry->clone;
456    $entry->status(MT::Entry::RELEASE()) if $publish;
457    $entry->title($item->{title}) if $item->{title};
458
459    $class->_apply_basename($entry, $item, \%param);
460
461    $entry->text($item->{description});
462    $entry->convert_breaks($item->{mt_convert_breaks})
463        if exists $item->{mt_convert_breaks};
464    $entry->allow_comments($item->{mt_allow_comments})
465        if exists $item->{mt_allow_comments};
466    for my $field (qw( allow_pings )) {
467        my $val = $item->{"mt_$field"};
468        next unless defined $val;
469        die _fault(MT->translate("Value for 'mt_[_1]' must be either 0 or 1 (was '[_2]')", $field, $val))
470            unless $val == 0 || $val == 1;
471        $entry->$field($val);
472    }
473    $entry->excerpt($item->{mt_excerpt}) if defined $item->{mt_excerpt};
474    $entry->text_more($item->{mt_text_more}) if defined $item->{mt_text_more};
475    $entry->keywords($item->{mt_keywords}) if defined $item->{mt_keywords};
476    if (my $tags = $item->{mt_tags}) {
477        require MT::Tag;
478        my $tag_delim = chr($author->entry_prefs->{tag_delim});
479        my @tags = MT::Tag->split($tag_delim, $tags);
480        $entry->set_tags(@tags);
481    }
482    if (my $urls = $item->{mt_tb_ping_urls}) {
483        no_utf8(@$urls);
484        $entry->to_ping_urls(join "\n", @$urls);
485    }
486    if (my $iso = $item->{dateCreated}) {
487        $entry->authored_on(MT::XMLRPCServer::Util::iso2ts($entry->blog_id, $iso))
488           || die MT::XMLRPCServer::_fault(MT->translate("Invalid timestamp format"));
489    }
490    $entry->discover_tb_from_entry();
491
492    MT->run_callbacks("api_pre_save.$obj_type", $mt, $entry,
493        $orig_entry)
494        || die MT::XMLRPCServer::_fault(MT->translate("PreSave failed [_1]", MT->errstr));
495
496    $entry->save;
497
498    my $changed = $class->_save_placements($entry, $item, \%param);
499    my @types = ( $obj_type );
500    if ($changed) {
501        push @types, 'folder'; # folders are the only type that can be
502                               # created in _save_placements
503    }
504    $blog->touch( @types );
505
506    MT->run_callbacks("api_post_save.$obj_type", $mt, $entry,
507        $orig_entry);
508
509    require MT::Log;
510    $mt->log({
511        message => $mt->translate("User '[_1]' (user #[_2]) edited [lc,_4] #[_3]", $author->name, $author->id, $entry->id, $entry->class_label),
512        level => MT::Log::INFO(),
513        class => $obj_type,
514        category => 'new',
515        metadata => $entry->id
516    });
517
518    if ($publish) {
519        $class->_publish($mt, $entry) or die _fault($class->errstr);
520    }
521    SOAP::Data->type(boolean => 1);
522}
523
524sub editPost {
525    my $class = shift;
526    my($entry_id, $user, $pass, $item, $publish);
527    if ($class eq 'blogger') {
528        (my($appkey), $entry_id, $user, $pass, my($content), $publish) = @_;
529        $item->{description} = $content;
530    }
531    else {
532        ($entry_id, $user, $pass, $item, $publish) = @_;
533    }
534    $class->_edit_entry( entry_id => $entry_id, user => $user, pass => $pass,
535        item => $item, publish => $publish );
536}
537
538sub editPage {
539    my $class = shift;
540    my($blog_id, $entry_id, $user, $pass, $item, $publish) = @_;
541    $class->_edit_entry( blog_id => $blog_id, entry_id => $entry_id,
542        user => $user, pass => $pass, item => $item, publish => $publish,
543        page => 1 );
544}
545
546sub getUsersBlogs {
547    my $class;
548    if (UNIVERSAL::isa($_[0] => __PACKAGE__)) {
549        $class = shift;
550    } else {
551        $class = __PACKAGE__;
552    }
553    my($appkey, $user, $pass) = @_;
554    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
555    my($author) = $class->_login($user, $pass);
556    die _fault(MT->translate("Invalid login")) unless $author;
557    require MT::Permission;
558    require MT::Blog;
559    my $iter = MT::Permission->load_iter({ author_id => $author->id });
560    my @res;
561    while (my $perms = $iter->()) {
562        next unless $perms->can_create_post;
563        my $blog = MT::Blog->load($perms->blog_id);
564        next unless $blog;
565        push @res, { url => SOAP::Data->type(string => $blog->site_url),
566                     blogid => SOAP::Data->type(string => $blog->id),
567                     blogName => SOAP::Data->type(string => encode_text($blog->name, undef, 'utf-8')) };
568    }
569    \@res;
570}
571
572sub getUserInfo {
573    my $class;
574    if (UNIVERSAL::isa($_[0] => __PACKAGE__)) {
575        $class = shift;
576    } else {
577        $class = __PACKAGE__;
578    }
579    my($appkey, $user, $pass) = @_;
580    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
581    my($author) = $class->_login($user, $pass);
582    die _fault(MT->translate("Invalid login")) unless $author;
583    my($fname, $lname) = map { encode_text($_, undef, 'utf-8') } split /\s+/, $author->name;
584    $lname ||= '';
585    { userid => SOAP::Data->type(string => $author->id),
586      firstname => SOAP::Data->type(string => $fname),
587      lastname => SOAP::Data->type(string => $lname),
588      nickname => SOAP::Data->type(string => encode_text($author->nickname, undef, 'utf-8')),
589      email => SOAP::Data->type(string => $author->email),
590      url => SOAP::Data->type(string => $author->url) };
591}
592
593sub _get_entries {
594    my $class = shift;
595    my %param = @_;
596    my($blog_id, $user, $pass, $num, $titles_only) =
597        @param{qw( blog_id user pass num titles_only )};
598    my $obj_type = $param{page} ? 'page' : 'entry';
599    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
600    my($author, $perms) = $class->_login($user, $pass, $blog_id);
601    die _fault(MT->translate("Invalid login")) unless $author;
602    die _fault(MT->translate("Permission denied.")) unless $perms && $perms->can_create_post;
603    require MT::Blog;
604    my $blog = MT::Blog->load($blog_id);
605    my $iter = MT->model($obj_type)->load_iter({ blog_id => $blog_id },
606        { 'sort' => 'authored_on',
607          direction => 'descend',
608          limit => $num });
609    my @res;
610    while (my $entry = $iter->()) {
611        my $co = sprintf "%04d%02d%02dT%02d:%02d:%02d",
612            unpack 'A4A2A2A2A2A2', $entry->authored_on;
613        my $row = { dateCreated => SOAP::Data->type(dateTime => $co),
614                    userid => SOAP::Data->type(string => $entry->author_id) };
615        $row->{ $param{page} ? 'page_id' : 'postid' } =
616            SOAP::Data->type(string => $entry->id);
617        if ($class eq 'blogger') {
618            $row->{content} = SOAP::Data->type(string => encode_text($entry->text, undef, 'utf-8'));
619        } else {
620            $row->{title} = SOAP::Data->type(string => encode_text($entry->title, undef, 'utf-8'));
621            unless ($titles_only) {
622                require MT::Tag;
623                my $tag_delim = chr($author->entry_prefs->{tag_delim});
624                my $tags = MT::Tag->join($tag_delim, $entry->tags);
625                $row->{description} = SOAP::Data->type(string => encode_text($entry->text, undef, 'utf-8'));
626                my $link = $entry->permalink;
627                $row->{link} = SOAP::Data->type(string => $link);
628                $row->{permaLink} = SOAP::Data->type(string => $link),
629                $row->{mt_basename} = SOAP::Data->type(string => encode_text($entry->basename, undef, 'utf-8'));
630                $row->{mt_allow_comments} = SOAP::Data->type(int => $entry->allow_comments);
631                $row->{mt_allow_pings} = SOAP::Data->type(int => $entry->allow_pings);
632                $row->{mt_convert_breaks} = SOAP::Data->type(string => $entry->convert_breaks);
633                $row->{mt_text_more} = SOAP::Data->type(string => encode_text($entry->text_more, undef, 'utf-8'));
634                $row->{mt_excerpt} = SOAP::Data->type(string => encode_text($entry->excerpt, undef, 'utf-8'));
635                $row->{mt_keywords} = SOAP::Data->type(string => encode_text($entry->keywords, undef, 'utf-8'));
636                $row->{mt_tags} = SOAP::Data->type(string => encode_text($tags, undef, 'utf-8'));
637            }
638        }
639        push @res, $row;
640    }
641    \@res;
642}
643
644sub getRecentPosts {
645    my $class = shift;
646    my ($blog_id, $user, $pass, $num);
647    if ($class eq 'blogger') {
648        (my($appkey), $blog_id, $user, $pass, $num) = @_;
649    }
650    else {
651        ($blog_id, $user, $pass, $num) = @_;
652    }
653    $class->_get_entries( blog_id => $blog_id, user => $user,
654        pass => $pass, num => $num );
655}
656
657sub getRecentPostTitles {
658    my $class = shift;
659    my ($blog_id, $user, $pass, $num) = @_;
660    $class->_get_entries( blog_id => $blog_id, user => $user,
661        pass => $pass, num => $num, titles_only => 1 );
662}
663
664sub getPages {
665    my $class = shift;
666    my ($blog_id, $user, $pass) = @_;
667    $class->_get_entries( blog_id => $blog_id, user => $user,
668        pass => $pass, page => 1 );
669}
670
671sub _delete_entry {
672    my $class = shift;
673    my %param = @_;
674    my ($blog_id, $entry_id, $user, $pass, $publish) =
675        @param{qw( blog_id entry_id user pass publish )};
676    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
677    my $obj_type = $param{page} ? 'page' : 'entry';
678    my $entry = MT->model($obj_type)->load($entry_id)
679        or die _fault(MT->translate("Invalid entry ID '[_1]'", $entry_id));
680    my($author, $perms) = $class->_login($user, $pass, $entry->blog_id);
681    die _fault(MT->translate("Invalid login")) unless $author;
682    die _fault(MT->translate("Permission denied."))
683        unless $perms && $perms->can_edit_entry($entry, $author);
684    $entry->remove;
685
686    $mt->log({
687        message => $mt->translate("Entry '[_1]' ([lc,_5] #[_2]) deleted by '[_3]' (user #[_4]) from xml-rpc", $entry->title, $entry->id, $author->name, $author->id, $entry->class_label),
688        level => MT::Log::INFO(),
689        class => 'system',
690        category => 'delete' 
691    });
692
693    if ($publish) {
694        $class->_publish($mt, $entry, 1) or die _fault($class->errstr);
695    }
696    SOAP::Data->type(boolean => 1);
697}
698
699sub deletePost {
700    my $class;
701    if (UNIVERSAL::isa($_[0] => __PACKAGE__)) {
702        $class = shift;
703    } else {
704        $class = __PACKAGE__;
705    }
706    my($appkey, $entry_id, $user, $pass, $publish) = @_;
707    $class->_delete_entry( entry_id => $entry_id, user => $user,
708        pass => $pass, publish => $publish );
709}
710
711sub deletePage {
712    my $class = shift;
713    my ($blog_id, $user, $pass, $entry_id) = @_;
714    $class->_delete_entry( blog_id => $blog_id, entry_id => $entry_id,
715        user => $user, pass => $pass, publish => 1, page => 1 );
716}
717
718sub _get_entry {
719    my $class = shift;
720    my %param = @_;
721    my($blog_id, $entry_id, $user, $pass) =
722        @param{qw( blog_id entry_id user pass )};
723    my $obj_type = $param{page} ? 'page' : 'entry';
724    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
725    my $entry = MT->model($obj_type)->load($entry_id)
726        or die _fault(MT->translate("Invalid entry ID '[_1]'", $entry_id));
727    if ($blog_id && $blog_id != $entry->blog_id) {
728        die _fault(MT->translate("Invalid entry ID '[_1]'", $entry_id));
729    }
730    my($author, $perms) = $class->_login($user, $pass, $entry->blog_id);
731    die _fault(MT->translate("Invalid login")) unless $author;
732    die _fault(MT->translate("Not privileged to get entry"))
733        unless $perms && $perms->can_edit_entry($entry, $author);
734    my $co = sprintf "%04d%02d%02dT%02d:%02d:%02d",
735        unpack 'A4A2A2A2A2A2', $entry->authored_on;
736    require MT::Blog;
737    my $blog = MT::Blog->load($entry->blog_id);
738    my $link = $entry->permalink;
739    require MT::Tag;
740    my $delim = chr($author->entry_prefs->{tag_delim});
741    my $tags = MT::Tag->join($delim, $entry->tags);
742
743    my $cats = [];
744    my $cat_data = $entry->__load_category_data();
745    if (scalar @$cat_data) {
746        my ($first_cat) = grep {  $_->[1] } @$cat_data;
747        my @cat_ids     = grep { !$_->[1] } @$cat_data;
748        unshift @cat_ids, $first_cat if $first_cat;
749        $cats = MT->model('category')->lookup_multi(
750            [ map { $_->[0] } @cat_ids ]);
751    }
752
753    my $basename = SOAP::Data->type(string => encode_text($entry->basename, undef, 'utf-8'));
754    {
755        dateCreated => SOAP::Data->type(dateTime => $co),
756        userid => SOAP::Data->type(string => $entry->author_id),
757        ($param{page} ? 'page_id' : 'postid') => SOAP::Data->type(string => $entry->id),
758        description => SOAP::Data->type(string => encode_text($entry->text, undef, 'utf-8')),
759        title => SOAP::Data->type(string => encode_text($entry->title, undef, 'utf-8')),
760        mt_basename => $basename,
761        wp_slug => $basename,
762        link => SOAP::Data->type(string => $link),
763        permaLink => SOAP::Data->type(string => $link),
764        categories => [ map { SOAP::Data->type(string => $_->label) } @$cats ],
765        mt_allow_comments => SOAP::Data->type(int => $entry->allow_comments),
766        mt_allow_pings => SOAP::Data->type(int => $entry->allow_pings),
767        mt_convert_breaks => SOAP::Data->type(string => $entry->convert_breaks),
768        mt_text_more => SOAP::Data->type(string => encode_text($entry->text_more, undef, 'utf-8')),
769        mt_excerpt => SOAP::Data->type(string => encode_text($entry->excerpt, undef, 'utf-8')),
770        mt_keywords => SOAP::Data->type(string => encode_text($entry->keywords, undef, 'utf-8')),
771        mt_tags => SOAP::Data->type(string => encode_text($tags, undef, 'utf-8')),
772    }
773}
774
775sub getPost {
776    my $class = shift;
777    my($entry_id, $user, $pass) = @_;
778    $class->_get_entry( entry_id => $entry_id, user => $user, pass => $pass );
779}
780
781sub getPage {
782    my $class = shift;
783    my ($blog_id, $entry_id, $user, $pass) = @_;
784    $class->_get_entry( blog_id => $blog_id, entry_id => $entry_id,
785        user => $user, pass => $pass, page => 1 );
786}
787
788sub supportedMethods {
789    [ 'blogger.newPost', 'blogger.editPost', 'blogger.getRecentPosts',
790      'blogger.getUsersBlogs', 'blogger.getUserInfo', 'blogger.deletePost',
791      'metaWeblog.getPost', 'metaWeblog.newPost', 'metaWeblog.editPost',
792      'metaWeblog.getRecentPosts', 'metaWeblog.newMediaObject',
793      'metaWeblog.getCategories', 'metaWeblog.deletePost',
794      'metaWeblog.getUsersBlogs',
795      'wp.newPage', 'wp.getPages', 'wp.getPage', 'wp.editPage',
796      'wp.deletePage',
797       # not yet supported: metaWeblog.getTemplate, metaWeblog.setTemplate
798      'mt.getCategoryList', 'mt.setPostCategories', 'mt.getPostCategories',
799      'mt.getTrackbackPings', 'mt.supportedTextFilters',
800      'mt.getRecentPostTitles', 'mt.publishPost', 'mt.getTagList' ];
801}
802
803sub supportedTextFilters {
804    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
805    my $filters = $mt->all_text_filters;
806    my @res;
807    for my $filter (keys %$filters) {
808        my $label = $filters->{$filter}{label};
809        if ('CODE' eq ref($label)) {
810            $label = $label->();
811        }
812        push @res, {
813            key => SOAP::Data->type(string => $filter),
814            label => SOAP::Data->type(string => $label)
815        };
816    }
817    \@res;
818}
819
820## getCategoryList, getPostCategories, and setPostCategories were
821## originally written by Daniel Drucker with the assistance of
822## Six Apart, then later modified by Six Apart.
823
824sub getCategoryList {
825    my $class = shift;
826    my($blog_id, $user, $pass) = @_;
827    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
828    my($author, $perms) = $class->_login($user, $pass, $blog_id);
829    die _fault(MT->translate("Invalid login")) unless $author;
830    die _fault(MT->translate("Permission denied."))
831        unless $perms && $perms->can_create_post;
832    require MT::Category;
833    my $iter = MT::Category->load_iter({ blog_id => $blog_id });
834    my @data;
835    while (my $cat = $iter->()) {
836        push @data, {
837            categoryName => SOAP::Data->type(string => encode_text($cat->label, undef, 'utf-8')),
838            categoryId => SOAP::Data->type(string => $cat->id)
839        };
840    }
841    \@data;
842}
843
844sub getCategories {
845    my $class = shift;
846    my($blog_id, $user, $pass) = @_;
847    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
848    my($author, $perms) = $class->_login($user, $pass, $blog_id);
849    die _fault(MT->translate("Invalid login")) unless $author;
850    die _fault(MT->translate("Permission denied."))
851        unless $perms && $perms->can_create_post;
852    require MT::Category;
853    my $iter = MT::Category->load_iter({ blog_id => $blog_id });
854    my @data;
855    my $blog = MT::Blog->load($blog_id);
856    require File::Spec;
857    while (my $cat = $iter->()) {
858        my $url = File::Spec->catfile($blog->site_url, archive_file_for( undef, $blog, 'Category', $cat ));
859        push @data, {
860            categoryId => SOAP::Data->type(string => encode_text($cat->id, undef, 'utf-8')),
861            parentId => ($cat->parent_category ? SOAP::Data->type(string => encode_text($cat->parent_category->id, undef, 'utf-8')) : undef),
862            categoryName => SOAP::Data->type(string => encode_text($cat->label, undef, 'utf-8')),
863            title => SOAP::Data->type(string => encode_text($cat->label, undef, 'utf-8')),
864            description => SOAP::Data->type(string => encode_text($cat->description, undef, 'utf-8')),
865            htmlUrl => SOAP::Data->type(string => encode_text($url, undef, 'utf-8')),
866        };
867    }
868    \@data;
869}
870
871sub getTagList {
872    my $class = shift;
873    my($blog_id, $user, $pass) = @_;
874    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
875    my($author, $perms) = $class->_login($user, $pass, $blog_id);
876    die _fault(MT->translate("Invalid login")) unless $author;
877    die _fault(MT->translate("Permission denied."))
878        unless $perms && $perms->can_create_post;
879    require MT::Tag;
880    require MT::ObjectTag;
881    my $iter = MT::Tag->load_iter(undef, { join => ['MT::ObjectTag', 'tag_id', { blog_id => $blog_id }, { unique => 1 } ] } );
882    my @data;
883    while (my $tag = $iter->()) {
884        push @data, {
885            tagName => SOAP::Data->type(string => encode_text($tag->name, undef, 'utf-8')),
886            tagId => SOAP::Data->type(string => $tag->id)
887        };
888    }
889    \@data;
890}
891
892sub getPostCategories {
893    my $class = shift;
894    my($entry_id, $user, $pass) = @_;
895    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
896    require MT::Entry;
897    my $entry = MT::Entry->load($entry_id)
898        or die _fault(MT->translate("Invalid entry ID '[_1]'", $entry_id));
899    my($author, $perms) = $class->_login($user, $pass, $entry->blog_id);
900    die _fault(MT->translate("Invalid login")) unless $author;
901    die _fault(MT->translate("Permission denied.")) unless $perms && $perms->can_create_post;
902    my @data;
903    my $prim = $entry->category;
904    my $cats = $entry->categories;
905    for my $cat (@$cats) {
906        my $is_primary = $prim && $cat->id == $prim->id ? 1 : 0;
907        push @data, {
908            categoryName => SOAP::Data->type(string => encode_text($cat->label, undef, 'utf-8')),
909            categoryId => SOAP::Data->type(string => $cat->id),
910            isPrimary => SOAP::Data->type(boolean => $is_primary),
911        };
912    }
913    \@data;
914}
915
916sub setPostCategories {
917    my $class = shift;
918    my($entry_id, $user, $pass, $cats) = @_;
919    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
920    require MT::Entry;
921    require MT::Placement;
922    my $entry = MT::Entry->load($entry_id)
923         or die _fault(MT->translate("Invalid entry ID '[_1]'", $entry_id));
924    my($author, $perms) = $class->_login($user, $pass, $entry->blog_id);
925    die _fault(MT->translate("Invalid login")) unless $author;
926    die _fault(MT->translate("Not privileged to set entry categories"))
927        unless $perms && $perms->can_edit_entry($entry, $author);
928    my @place = MT::Placement->load({ entry_id => $entry_id });
929    for my $place (@place) {
930         $place->remove;
931    }
932    ## Keep track of which category is named the primary category.
933    ## If the first structure in the array does not have an isPrimary
934    ## key, we just make it the primary category; if it does, we use
935    ## that flag to determine the primary category.
936    my $is_primary = 1;
937    for my $cat (@$cats) {
938         my $place = MT::Placement->new;
939         $place->entry_id($entry_id);
940         $place->blog_id($entry->blog_id);
941         if (defined $cat->{isPrimary} && $is_primary) {
942             $place->is_primary($cat->{isPrimary});
943         } else {
944             $place->is_primary($is_primary);
945         }
946         ## If we just set the is_primary flag to 1, we don't want to
947         ## make any other categories primary.
948         $is_primary = 0 if $place->is_primary;
949         $place->category_id($cat->{categoryId});
950         $place->save
951              or die _fault(MT->translate("Saving placement failed: [_1]", $place->errstr));
952    }
953    SOAP::Data->type(boolean => 1);
954}
955
956sub getTrackbackPings {
957    my $class = shift;
958    my($entry_id) = @_;
959    require MT::Trackback;
960    require MT::TBPing;
961    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
962    my $tb = MT::Trackback->load({ entry_id => $entry_id })
963        or return [];
964    my $iter = MT::TBPing->load_iter({ tb_id => $tb->id });
965    my @data;
966    while (my $ping = $iter->()) {
967        push @data, {
968            pingTitle => SOAP::Data->type(string => encode_text($ping->title, undef, 'utf-8')),
969            pingURL => SOAP::Data->type(string => $ping->source_url),
970            pingIP => SOAP::Data->type(string => $ping->ip),
971        };
972    }
973    \@data;
974}
975
976sub publishPost {
977    my $class = shift;
978    my($entry_id, $user, $pass) = @_;
979    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
980    require MT::Entry;
981    my $entry = MT::Entry->load($entry_id)
982        or die _fault(MT->translate("Invalid entry ID '[_1]'", $entry_id));
983    my($author, $perms) = $class->_login($user, $pass, $entry->blog_id);
984    die _fault(MT->translate("Invalid login")) unless $author;
985    die _fault(MT->translate("Not privileged to edit entry"))
986        unless $perms && $perms->can_edit_entry($entry, $author);
987    $mt->rebuild_entry( Entry => $entry, BuildDependencies => 1 )
988        or die _fault(MT->translate("Publish failed: [_1]", $mt->errstr));
989    SOAP::Data->type(boolean => 1);
990}
991
992sub runPeriodicTasks {
993    my $class = shift;
994    my ($user, $pass) = @_;
995
996    my $mt = MT::XMLRPCServer::Util::mt_new();
997    my $author = $class->_login($user, $pass);
998    die _fault(MT->translate("Invalid login")) unless $author;
999
1000    $mt->run_tasks;
1001
1002    { responseCode => 'success' }
1003}
1004
1005sub publishScheduledFuturePosts {
1006    my $class = shift;
1007    my ($blog_id, $user, $pass) = @_;
1008
1009    my $mt = MT::XMLRPCServer::Util::mt_new();
1010    my $author = $class->_login($user, $pass);
1011    die _fault(MT->translate("Invalid login")) unless $author;
1012    my $blog = MT::Blog->load($blog_id);
1013
1014    my $now = time;
1015    # Convert $now to user's timezone, which is how future post dates
1016    # are stored.
1017    $now = MT::Util::offset_time($now);
1018    $now = strftime("%Y%m%d%H%M%S", gmtime($now));
1019
1020    my $iter = MT::Entry->load_iter({
1021        blog_id => $blog->id,
1022        class => '*',
1023        status => MT::Entry::FUTURE()},
1024        {'sort' => 'authored_on',
1025         direction => 'descend'
1026    });
1027    my @queue;
1028    while (my $i = $iter->()) {
1029        push @queue, $i->id();
1030    }
1031
1032    my $changed = 0;
1033    my $total_changed = 0;
1034    my @results;
1035    my %types;
1036    foreach my $entry_id (@queue) {
1037        my $entry = MT::Entry->load($entry_id);
1038        if ($entry->authored_on <= $now) {
1039            $entry->status(MT::Entry::RELEASE());
1040            $entry->discover_tb_from_entry();
1041            $entry->save
1042                or die $entry->errstr;
1043
1044            $types{$entry->class} = 1;
1045            start_background_task(sub {
1046                $mt->rebuild_entry( Entry => $entry, Blog => $blog )
1047                    or die $mt->errstr;
1048            });
1049            $changed++;
1050            $total_changed++;
1051        }
1052    }
1053    $blog->touch( keys %types ) if $changed;
1054    $blog->save if $changed && (keys %types);
1055
1056    if ($changed) {
1057        $mt->rebuild_indexes( Blog => $blog )
1058            or die $mt->errstr;
1059    }
1060    { responseCode => 'success', 
1061      publishedCount => $total_changed,
1062    };
1063}
1064
1065sub getNextScheduled {
1066    my $class = shift;
1067    my ($user, $pass) = @_;
1068
1069    my $mt = MT::XMLRPCServer::Util::mt_new();
1070    my $author = $class->_login($user, $pass);
1071    die _fault(MT->translate("Invalid login")) unless $author;
1072
1073    my $next_scheduled = MT::get_next_sched_post_for_user($author->id());
1074
1075    { nextScheduledTime => $next_scheduled };
1076}
1077
1078sub setRemoteAuthToken {
1079    my $class = shift;
1080    my ($user, $pass, $remote_auth_username, $remote_auth_token) = @_;
1081    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
1082    my($author) = $class->_login($user, $pass);
1083    die _fault(MT->translate("Invalid login")) unless $author;
1084    $author->remote_auth_username($remote_auth_username);
1085    $author->remote_auth_token($remote_auth_token);
1086    $author->save();
1087    1;
1088}
1089
1090sub newMediaObject {
1091    my $class = shift;
1092    my($blog_id, $user, $pass, $file) = @_;
1093    my $mt = MT::XMLRPCServer::Util::mt_new();   ## Will die if MT->new fails.
1094    my($author, $perms) = $class->_login($user, $pass, $blog_id);
1095    die _fault(MT->translate("Invalid login")) unless $author;
1096    die _fault(MT->translate("Not privileged to upload files"))
1097        unless $perms && $perms->can_upload;
1098    require MT::Blog;
1099    require File::Spec;
1100    my $blog = MT::Blog->load($blog_id);
1101    my $fname = $file->{name} or die _fault(MT->translate("No filename provided"));
1102    if ($fname =~ m!\.\.|\0|\|!) {
1103        die _fault(MT->translate("Invalid filename '[_1]'", $fname));
1104    }
1105    my $local_file = File::Spec->catfile($blog->site_path, $file->{name});
1106    my $fmgr = $blog->file_mgr;
1107    my($vol, $path, $name) = File::Spec->splitpath($local_file);
1108    $path =~ s!/$!! unless $path eq '/';  ## OS X doesn't like / at the end in mkdir().
1109    unless ($fmgr->exists($path)) {
1110        $fmgr->mkpath($path)
1111            or die _fault(MT->translate("Error making path '[_1]': [_2]", $path, $fmgr->errstr));
1112    }
1113    defined(my $bytes = $fmgr->put_data($file->{bits}, $local_file, 'upload'))
1114        or die _fault(MT->translate("Error writing uploaded file: [_1]", $fmgr->errstr));
1115    my $url = $blog->site_url . $fname;
1116
1117    require File::Basename;
1118    my $local_basename = File::Basename::basename($local_file);
1119    my $ext =
1120        ( File::Basename::fileparse( $local_file, qr/[A-Za-z0-9]+$/ ) )[2];
1121    eval { require Image::Size; };
1122    die _fault(MT->translate("Perl module Image::Size is required to determine width and height of uploaded images.")) if $@;
1123    my ( $w, $h, $id ) = Image::Size::imgsize($local_file);
1124
1125    require MT::Asset;
1126    my $asset_pkg = MT::Asset->handler_for_file($local_basename);
1127    my $is_image  = defined($w)
1128      && defined($h)
1129      && $asset_pkg->isa('MT::Asset::Image');
1130    my $asset;
1131    if (!($asset = $asset_pkg->load(
1132                { file_path => $local_file, blog_id => $blog_id })))
1133    {
1134        $asset = $asset_pkg->new();
1135        $asset->file_path($local_file);
1136        $asset->file_name($local_basename);
1137        $asset->file_ext($ext);
1138        $asset->blog_id($blog_id);
1139        $asset->created_by( $author->id );
1140    }
1141    else {
1142        $asset->modified_by( $author->id );
1143    }
1144    my $original = $asset->clone;
1145    $asset->url($url);
1146    if ($is_image) {
1147        $asset->image_width($w);
1148        $asset->image_height($h);
1149    }
1150    $asset->mime_type($file->{type});
1151    $asset->save;
1152
1153    $blog->touch('asset');
1154    $blog->save;
1155
1156    MT->run_callbacks(
1157        'api_upload_file.' . $asset->class,
1158        File => $local_file, file => $local_file,
1159        Url => $url, url => $url,
1160        Size => $bytes, size => $bytes,
1161        Asset => $asset, asset => $asset,
1162        Type => $asset->class, type => $asset->class,
1163        Blog => $blog,blog => $blog);
1164    if ($is_image) {
1165        MT->run_callbacks(
1166            'api_upload_image',
1167            File => $local_file, file => $local_file,
1168            Url => $url, url => $url,
1169            Size => $bytes, size => $bytes,
1170            Asset => $asset, asset => $asset,
1171            Height => $h, height => $h,
1172            Width => $w, width => $w,
1173            Type => 'image', type => 'image',
1174            ImageType => $id, image_type => $id,
1175            Blog => $blog, blog => $blog);
1176    }
1177
1178    { url => SOAP::Data->type(string => $url) };
1179}
1180
1181## getTemplate and setTemplate are not applicable in MT's template
1182## structure, so they are unimplemented (they return a fault).
1183## We assign it twice to get rid of "setTemplate used only once" warnings.
1184
1185sub getTemplate {
1186    die _fault(MT->translate(
1187        "Template methods are not implemented, due to differences between the Blogger API and the Movable Type API."));
1188}
1189*setTemplate = *setTemplate = \&getTemplate;
1190
1191## The above methods will be called as blogger.newPost, blogger.editPost,
1192## etc., because we are implementing Blogger's API. Thus, the empty
1193## subclass.
1194package blogger;
1195BEGIN { @blogger::ISA = qw( MT::XMLRPCServer ); }
1196
1197package metaWeblog;
1198BEGIN { @metaWeblog::ISA = qw( MT::XMLRPCServer ); }
1199
1200package mt;
1201BEGIN { @mt::ISA = qw( MT::XMLRPCServer ); }
1202
1203package wp;
1204BEGIN { @wp::ISA = qw( MT::XMLRPCServer ); }
1205
12061;
1207__END__
1208
1209=head1 NAME
1210
1211MT::XMLRPCServer
1212
1213=head1 SYNOPSIS
1214
1215An XMLRPC API interface for communicating with Movable Type.
1216
1217=head1 CALLBACKS
1218
1219=over 4
1220
1221=item api_pre_save.entry
1222=item api_pre_save.page
1223
1224    callback($eh, $mt, $entry, $original_entry)
1225
1226Called before saving a new or existing entry. If saving a new entry, the
1227$original_entry will have an unassigned 'id'. This callback is executed
1228as a filter, so your handler must return 1 to allow the entry to be saved.
1229
1230=item api_post_save.entry
1231=item api_post_save.page
1232
1233    callback($eh, $mt, $entry, $original_entry)
1234
1235Called after saving a new or existing entry. If saving a new entry, the
1236$original_entry will have an unassigned 'id'.
1237
1238=item api_upload_file
1239
1240    callback($eh, %params)
1241
1242This callback is invoked for each file the user uploads to the weblog.
1243This callback is similar to the CMSUploadFile callback found in
1244C<MT::App::CMS>.
1245
1246=back
1247
1248=head2 Parameters
1249
1250=over 4
1251
1252=item File
1253
1254The full physical file path of the uploaded file.
1255
1256=item Url
1257
1258The full URL to the file that has been uploaded.
1259
1260=item Type
1261
1262For this callback, this value is currently always 'file'.
1263
1264=item Blog
1265
1266The C<MT::Blog> object associated with the newly uploaded file.
1267
1268=back
1269
1270=cut
Note: See TracBrowser for help on using the browser.